Another script executing Seismic Unix commands was run to convert the SU data file to a postscript file, and then in turn using an ImageMagick command to convert the postscript file to a JPEG.
The command line example is:
plotchirp 0 0.02 l4f1.001 7 98
This runs the plotchirp script with the parameters of start time of trace 0, end time of trace 0.02 seconds, l4f1.001 is the seismic file, 7 refers to the plot height in inches, and 98 is the percent black clip (where higher is lighter).
The plotchirp script is as follows:
plotchirp:
#! /bin/csh
## PLOTCHIRP
echo "Process plotchirp usage:"
echo " plotchirp tmin tmax sufile hbox clip"
echo " tmin and tmax (seconds) to define the vertical plot window"
echo " ie, 0 0.25 (window 0 to 250 ms)"
echo " the SU input file excluding the .su extension"
echo " hbox is the vertical plot size in inches"
echo " enter the % black clip ie, 95 (higher is lighter)"
echo " "
# get number of traces to be used in plot scale
echo "getting the total number of traces"
set numtraces = `surange < $3.su | grep traces | awk ' {print($1)}' `
echo "number of traces = "$numtraces
# get ffid range for input
echo "getting the range of FFID's"
set ffidmin = `surange < $3.su | grep tracr | awk ' {print($2)}' `
set ffidmax = `surange < $3.su | grep tracr | awk ' {print($3)}' `
echo "The minimum FFID is "$ffidmin
echo "The maximum FFID is "$ffidmax
echo " "
echo "Setting the sort order (data window), Set gain parameters"
suwind key=tracr min=$ffidmin max=$ffidmax itmin=$1 tmin=$1 tmax=$2 verbose=0 < $3.su | \
suchw key1=delrt a=0 | \
suchw key1=tstat a=0 | suchw key1=muts a=0 | suchw key1=mute a=0 > $3.tmp
echo "Set scaling for PS plot"
# set the plot X size based on the number of traces/inch
set wbox = `expr $numtraces / 40`
echo "the plot length =" $wbox "inches"
echo
# set the plot Y size (hbox) in inches
set tmin = $1
echo "tmin ="$tmin
set tmax = $2
echo "tmax ="$tmax
set hbox = $4
echo "the plot height=" $hbox "inches"
# PLOT POSTSCRIPT IMAGE
# Change percentile for determining black clip value to adjust plot contrast
# Higher bperc gives lighter plot - wclip=0 sets 0 and - amp. to white
echo "Making the PostScript plot"
supsimage wbox=$wbox hbox=$hbox \
ybox=0.5 \
x1beg=$1 x1end=$2 \
d1num=0.01 d2num=500 \
d2=1 \
n1tic=10 n2tic=5 \
bperc=$5 wclip=0 \
grid1=dot grid2=dot \
title="424 Chirp $3 SHOTS $ffidmin-$ffidmax" \
label1="TWT [s]" label2="SHOT" \
< $3.tmp > ../ps_files/$3.ps
rm $3.tmp
echo "Making jpeg"
convert ../ps_files/$3.ps ../jpeg_files/$3.jpg
# Save the processing runline history for future processing
echo "plotchirp $1 $2 $3 $4 $5" >> Proc.log
# Remove files not needed
rm ../ps_files/*.ps
